M5StackからBLEでiOSアプリに送信してスイッチを駆動

こんにちはRoboTakaoです。

前回はiOSアプリからBLEでM5Stackにデータ送信してLEDを点灯させてみました。

今回はM5StackからBLEでiOSアプリにデータ送信してiOSアプリ上のスイッチを駆動してみます。



前回のコードに対してM5Stack側のスケッチのみ変更しました。

スケッチの説明

setValueでStringを送信します。
“Pressed”に”*”を付けて、iOSアプリ側でデータの終わりを判別しています。

pTxCharacteristic->setValue((std::string)"Pressed*");
pTxCharacteristic->notify();

AとBボタンを押すとiOS側のスライドスイッチが動きます。



サンプルスケッチ

/*
    Video: https://www.youtube.com/watch?v=oCMOYS71NIU
    Based on Neil Kolban example for IDF: https://github.com/nkolban/esp32-snippets/blob/master/cpp_utils/tests/BLE%20Tests/SampleNotify.cpp
    Ported to Arduino ESP32 by Evandro Copercini

   Create a BLE server that, once we receive a connection, will send periodic notifications.
   The service advertises itself as: 6E400001-B5A3-F393-E0A9-E50E24DCCA9E
   Has a characteristic of: 6E400002-B5A3-F393-E0A9-E50E24DCCA9E - used for receiving data with "WRITE" 
   Has a characteristic of: 6E400003-B5A3-F393-E0A9-E50E24DCCA9E - used to send data with  "NOTIFY"

   The design of creating the BLE server is:
   1. Create a BLE Server
   2. Create a BLE Service
   3. Create a BLE Characteristic on the Service
   4. Create a BLE Descriptor on the characteristic
   5. Start the service.
   6. Start advertising.

   In this example rxValue is the data received (only accessible inside that function).
   And txValue is the data to be sent, in this example just a byte incremented every second. 
*/
#include 
#include 
#include 
#include 
#include 

BLEServer *pServer = NULL;
BLECharacteristic * pTxCharacteristic;
bool deviceConnected = false;
bool oldDeviceConnected = false;
uint8_t txValue = 0;

int LEDPinNo = 22;

// See the following for generating UUIDs:
// https://www.uuidgenerator.net/

#define SERVICE_UUID           "6E400001-B5A3-F393-E0A9-E50E24DCCA9E" // UART service UUID
#define CHARACTERISTIC_UUID_RX "6E400002-B5A3-F393-E0A9-E50E24DCCA9E"
#define CHARACTERISTIC_UUID_TX "6E400003-B5A3-F393-E0A9-E50E24DCCA9E"


class MyServerCallbacks: public BLEServerCallbacks {
    void onConnect(BLEServer* pServer) {
      deviceConnected = true;
    };

    void onDisconnect(BLEServer* pServer) {
      deviceConnected = false;
    }
};

class MyCallbacks: public BLECharacteristicCallbacks {
    void onWrite(BLECharacteristic *pCharacteristic) {
      std::string rxValue = pCharacteristic->getValue();

      M5.Lcd.println("Receive");
      Serial.println("Receive");
      

      // 文字列として受信した値の読み取り開始位置
      int from = 0;

      // メッセージの処理が終了したことを示すフラグ
      boolean noMoreEvent = false;

      // メッセージの処理が終了するまで以下を繰り返す
      while (!noMoreEvent) {
        // 受信した文字列の中で「*」を探す
        int index = rxValue.find("*", from);

        // もし見つからなければ
        if (index < 0) {
          // 処理が終了したと判断してフラグをセット
          noMoreEvent = true;
        }
        // もし見つかったら
        else {
          // 部分文字列をコマンドとして取り出し
          std::string command = rxValue.substr(from, index);

          // コマンドに応じて処理
          if (command == "On") {
            digitalWrite(LEDPinNo, HIGH);
            M5.Lcd.println("LED On");
            Serial.println("LED On");
          } else if (command == "Off") {
            digitalWrite(LEDPinNo, LOW);
            M5.Lcd.println("LED Off");
            Serial.println("LED Off");
          }

          // 次に処理する読み取り開始位置を更新
          from = index + 1;
        }
      }
    }
};


void setup() {
  M5.begin();
  
  Serial.begin(115200);

  pinMode(LEDPinNo, OUTPUT); //22pin OUTPUT mode

  // Create the BLE Device
  BLEDevice::init("UART Service");

  // Create the BLE Server
  pServer = BLEDevice::createServer();
  pServer->setCallbacks(new MyServerCallbacks());

  // Create the BLE Service
  BLEService *pService = pServer->createService(SERVICE_UUID);

  // Create a BLE Characteristic
  pTxCharacteristic = pService->createCharacteristic(
										CHARACTERISTIC_UUID_TX,
										BLECharacteristic::PROPERTY_NOTIFY
									);
                      
  pTxCharacteristic->addDescriptor(new BLE2902());

  BLECharacteristic * pRxCharacteristic = pService->createCharacteristic(
											 CHARACTERISTIC_UUID_RX,
											BLECharacteristic::PROPERTY_WRITE
										);

  pRxCharacteristic->setCallbacks(new MyCallbacks());

  // Start the service
  pService->start();

  // Start advertising
  pServer->getAdvertising()->start();
  M5.Lcd.println("Waiting a client connection to notify...");
  Serial.println("Waiting a client connection to notify...");
}

void loop() {

    // Button A B
    if (deviceConnected) {
        if(M5.BtnA.wasPressed()) {
            M5.Lcd.printf("wasPressed A \r\n");
            Serial.println("wasPressed A \r\n");
            pTxCharacteristic->setValue((std::string)"Pressed*");
            pTxCharacteristic->notify();
        }

       if(M5.BtnB.wasPressed())
       {
            M5.Lcd.printf("wasPressed B \r\n");
            Serial.println("wasPressed B \r\n");
            pTxCharacteristic->setValue((std::string)"Released*");
            pTxCharacteristic->notify();
       }
    }

    // disconnecting
    if (!deviceConnected && oldDeviceConnected) {
        delay(500); // give the bluetooth stack the chance to get things ready
        pServer->startAdvertising(); // restart advertising
        M5.Lcd.println("start advertising");
        Serial.println("start advertising");
        oldDeviceConnected = deviceConnected;
    }
    // connecting
    if (deviceConnected && !oldDeviceConnected) {
		// do stuff here on connecting
        oldDeviceConnected = deviceConnected;
    }

    M5.update();
}

それでは今回はこの辺で失礼します！ありがとうございます。

M5Stack関連投稿
1)M5StackとりあえずArduinoIDEで使う初期設定した。(macOS)
2)M5Stack Arduino IDE のサンプルスケッチを試してみた
3)M5Stack アバターを試してみた（Arduino IDE） Avatar
4)M5Stack とりあえずLチカ
5)M5Stack サーボ動かしてみた
6)M5Stackで16チャンネルサーボドライバPCA9685を使ってみる
7)M5StackでBluetooth Low Energy (BLE)のテストをしてみた
8)M5StackでWiFiのテストをしてみた
9)iOSアプリからBLEでM5Stack に送信してLEDを点灯させてみた