自作のメカナムホールとM5StickCでローバーを作ってみた。モーション改善

こんにちはRoboTakaoです。
これまで、M5StickCとメカナムホールでローバーを作ってきました。

今回は少しモーションを改善しました。



動作確認

信地回転と超信地回転に加えて、ドリフト回転？を追加
スムーズに動作してきているように思います。



スケッチ

#define BLYNK_PRINT Serial
#define BLYNK_USE_DIRECT_CONNECT

#include <M5StickC.h>
#include <BlynkSimpleEsp32_BLE.h>
#include <BLEDevice.h>
#include <BLEServer.h>

char auth[] = "jZpGVzEJgw4g3SkzJkdpeAgdTGvRWAoW";  //メールで送られるAuth Token

const uint8_t Srv_RF = 26, Srv_RR = 0, Srv_LF = 32, Srv_LR = 33; //GPIO No.
const uint8_t srvCH_RF = 0, srvCH_RR = 1, srvCH_LF = 2, srvCH_LR = 3; //チャンネル
const double PWM_Hz = 50;   //PWM周波数
const uint8_t PWM_level = 16; //PWM 16bit(0～65535)

int mRF = 0, mRR = 0, mLF = 0, mLR = 0;

int pulseMIN = 2295;  //700μsec 50Hz 16bit
int pulseMAX = 7533;  //2300μsec 50Hz 16bit

int cont_max = 100;
int cont_thres = 40;
int cont_thres2 = 10;

void setup() {
  Serial.begin(151200);
  m5.begin();
  pinMode(Srv_RF, OUTPUT);
  pinMode(Srv_RR, OUTPUT);
  pinMode(Srv_LF, OUTPUT);
  pinMode(Srv_LR, OUTPUT);

  Blynk.setDeviceName("Blynk");
  Blynk.begin(auth);

  M5.Lcd.print("NX12 TEST");
  
  //モータのPWMのチャンネル、周波数の設定
  ledcSetup(srvCH_RF, PWM_Hz, PWM_level);
  ledcSetup(srvCH_RR, PWM_Hz, PWM_level);
  ledcSetup(srvCH_LF, PWM_Hz, PWM_level);
  ledcSetup(srvCH_LR, PWM_Hz, PWM_level);

  //モータのピンとチャンネルの設定
  ledcAttachPin(Srv_RF, srvCH_RF);
  ledcAttachPin(Srv_RR, srvCH_RR);
  ledcAttachPin(Srv_LF, srvCH_LF);
  ledcAttachPin(Srv_LR, srvCH_LR);
}

//右ジョイスティックのデータ受信
BLYNK_WRITE(V0) {
  int x = param[0].asInt();
  int y = param[1].asInt();

  if(abs(y) > cont_thres){
    if(x > cont_thres){  //前輪旋回
      mRF = y;
      mRR = 0;
      mLF = -y;
      mLR = 0;
    }else if(x < -cont_thres){  //後輪旋回
      mRF = 0;
      mRR = y;
      mLF = 0;
      mLR = -y;
    }else{  //超信地旋回
      mRF = y;
      mRR = y;
      mLF = -y;
      mLR = -y;
    }
  }else if(cont_thres2 < y && y < cont_thres){
    if(x > cont_thres){  //右前信地旋回
      mRF = x;
      mRR = x;
      mLF = 0;
      mLR = 0;
    }else if(x < -cont_thres){  //右信地旋回
      mRF = 0;
      mRR = 0;
      mLF = x;
      mLR = x;
    }
  }else if(-cont_thres < y && y < -cont_thres2){
    if(x > cont_thres){    //左前信地旋回
      mRF = 0;
      mRR = 0;
      mLF = x;
      mLR = x;
    }else if(x < -cont_thres){  //左後信地旋回
      mRF = x;
      mRR = x;
      mLF = 0;
      mLR = 0;
    }
  }else if(abs(y) <= cont_thres2 && abs(x)>cont_thres){  //前後進
    mRF = x;
    mRR = x;
    mLF = x;
    mLR = x;
  }else{
    mRF = 0;
    mRR = 0;
    mLF = 0;
    mLR = 0;
  }
}

//左ジョイスティックのデータ受信
BLYNK_WRITE(V1) {
  int x = param[0].asInt();
  int y = param[1].asInt();

  if(y < -cont_thres){
    if(x > cont_thres){  //右斜め前
      mRF = 0;
      mRR = -y;
      mLF = -y;
      mLR = 0;
    }else if(x < -cont_thres){  //右斜め後
      mRF = y;
      mRR = 0;
      mLF = 0;
      mLR = y;
    }else{  //右スライド
      mRF = y;
      mRR = -y;
      mLF = -y;
      mLR = y;
    }
  }else if(y > cont_thres){
    if(x > cont_thres){  //左斜め前
      mRF = y;
      mRR = 0;
      mLF = 0;
      mLR = y;
    }else if(x < -cont_thres){  //左斜め後
      mRF = 0;
      mRR = -y;
      mLF = -y;
      mLR = 0;
    }else{  //左スライド
      mRF = y;
      mRR = -y;
      mLF = -y;
      mLR = y;
    }
  }else if(abs(x) > cont_thres){   //前後進
    mRF = x;
    mRR = x;
    mLF = x;
    mLR = x;
  }else{
    mRF = 0;
    mRR = 0;
    mLF = 0;
    mLR = 0;
  }
}


void motor_drive(int motor_RF, int motor_RR, int motor_LF, int motor_LR){
    motor_RF = map(motor_RF, -cont_max, cont_max, pulseMIN, pulseMAX);
    motor_RR = map(motor_RR, -cont_max, cont_max, pulseMIN, pulseMAX);
    motor_LF = map(motor_LF, -cont_max, cont_max, pulseMIN, pulseMAX);
    motor_LR = map(motor_LR, -cont_max, cont_max, pulseMIN, pulseMAX);
  
    ledcWrite(srvCH_RF, motor_RF);
    ledcWrite(srvCH_RR, motor_RR);
    ledcWrite(srvCH_LF, motor_LF);
    ledcWrite(srvCH_LR, motor_LR);
}

void loop() {
  M5.update();
  Blynk.run();
  
  motor_drive(-mRF, -mRR, mLF, mLR);
  delay(10);
}

Blynkのジョイスティック設定